          TITLE    'CKD - CRASH DUMP OVERLAY'                                   
          SYSTEM   SIG5P                                                        
         SYSTEM   OPTIONS                                                       
          DEF      A:CKD,CKDXIT                                                 
OLAYFLAG EQU      'CKD'                                                         
         TITLE    'PROCS AND STUFF FOR CKD'                                     
*                                                                               
*                                                                               
WRITE    CNAME    1                                                             
SETINDEX CNAME    1                                                             
READ     CNAME    1                                                             
CLOSEIT  CNAME    1                                                             
         PROC                                                                   
LF       CAL1,NAME AF(1)-TTTT,R7    POINT INTO TEMP SPACE                       
         PEND                                                                   
*                                                                               
*                                                                               
* PROC TO SIMPLIFY PRINT OPERATIONS                                             
*                                                                               
PRINT    CNAME                                                                  
         PROC                                                                   
LF       RES      0                                                             
         DO       CF(2)=TOP                                                     
         LI,R13   BIT23                                                         
         AWM,R13  LODCB-TTTT,R7     SET VFC                                     
         FIN                                                                    
*                                                                               
         LI,R13   AF(1)-TTTT                                                    
         AW,R13   R7                MAKE PTR TO MSG IN TEMP                     
         AND,R13  M17               MASK                                        
         STW,R13  LOBUFPTR-TTTT,R7                                              
*                                                                               
         LB,R13   AF(1)             GET BYTE COUNT                              
         STW,R13  LOBC-TTTT,R7                                                  
*                                                                               
         WRITE    FPT4                                                          
*                                                                               
         DO       CF(2)=TOP                                                     
         LI,R13   -BIT23                                                        
         AWM,R13  LODCB-TTTT,R7     RESET VFC                                   
         FIN                                                                    
         PEND                                                                   
*                                                                               
TOP      EQU      1                                                             
*                                                                               
*                                                                               
* SYMBOL TABLE GENERATOR                                                        
*                                                                               
SYMBOL   CNAME                                                                  
         PROC                                                                   
LF       TEXT     AF(1)                                                         
         DATA     AF(2)                                                         
         PEND                                                                   
*                                                                               
         SYSTEM   CPRMON                                                        
*                                                                               
         TITLE    'CRASH DUMP OVERLAY'                                          
*                                                                               
* THIS READS A CRASH OFF THE CK AREA AND OUTPUTS A FORMATTED                    
* DUMP ON THE LINE PRINTER  (LO OP-LABEL)                                       
*                                                                               
CKD      RES      0                                                             
A:CKD    EQU      CKD                                                           
         PUSH     R15                                                           
*                                                                               
         LI,R7    TEMPEND-TTTT      GET SPACE FOR FPT'S                         
         BAL,R8   GETTEMP           RETURN PTR IN R7                            
         B        STOPP             CANT GET SPACE                              
*                                                                               
         ENABLE                                                                 
         LI,R6    TEMPEND-TTTT-1    MOVE FPT'S TO TEMP SPACE                    
         LW,R0    TTTT,R6                                                       
         STW,R0   *R7,R6                                                        
         BDR,R6   %-2                                                           
*                                                                               
         PUSH     2,R3              SAVE LIMITS OF DUMP                         
*                                                                               
          LB,R6    R7                SAVE LENGTH                                
          LI,R5    0                                                            
          STB,R5   R7                CLEAR LENGTH IN R7                         
*                                                                               
         AWM,R7   FPT4-TTTT,R7                                                  
*                                                                               
          STB,R6   R7                RESTORE LENGTH IN R7                       
         PRINT,TOP TOPMSG                                                       
         PRINT    SYMHEAD                                                       
         LI,R14   SYMBOL                                                        
         LI,R6    1                 PTR TO FIRST SYMBOL                         
LOOP0    LI,R5    4                 NUMBER OF SYMBOLS/LINE                      
         LI,R4    SYMHEAD-TTTT+1    POINTER TO SYMBOL PRINT BUFF                
LOOP1    LCI      3                 SYMBOL SIZE                                 
         LM,R1    *R14,R6           GET SYMBOL                                  
         LCI      2                                                             
         STM,R1   *R7,R4            STORE NAME PART                             
         AI,R4    2                                                             
         BAL,R0   CONVERT2          CONVERT VALUE TO EBCDIC                     
         LCI      2                                                             
         STM,R2   *R7,R4            STORE VALUE                                 
         AI,R4    3                                                             
*                                                                               
         AI,R6    3                 INCREMENT SYMBOL PTR                        
         CW,R6    *R14              IS THIS THE LAST SYMBOL                     
         BG       SYMBDONE          YES                                         
         BDR,R5   LOOP1             NO, LOOP                                    
*                                                                               
         PRINT    SYMHEAD           PRINT EACH LINE AS DONE                     
*                                                                               
         LW,R5    Y04               KEYIN BIT                                   
         CW,R5    K:CTST            IS INTERRUPT SET                            
         BAZ      LOOP0             IF NOT LOOP                                 
         LI,R4    0                 OTHERWISE STOP SYMBOLS                      
         STS,R4   K:CTST            RESET BIT                                   
         B        NOSYMBOL          GO AND DO DUMP                              
*                                                                               
***************************************************************                 
LOOP2    RES      0                                                             
         LCI      5                                                             
         LM,R8    SYMFILL           FILL ER FOR BLANK SYMBOLS                   
         STM,R8   *R7,R4            FILL IN REST OF LINE                        
         AI,R4    5                                                             
SYMBDONE BDR,R5   LOOP2             LOOP TIL LAST OF LINE                       
*                                                                               
         PRINT    SYMHEAD           PRINT LAST SYMBOL LINE                      
NOSYMBOL RES      0                                                             
         BAL,R8   RELTEMP           RELEASE SPACE                               
*                                                                               
         PULL     2,R3                                                          
         BAL,R0   CKD2              DUMP CORE                                   
*                                                                               
STOPP    PULL     R15                                                           
CKDXIT    B        *R15              AND EXIT                                   
**************************************                                          
         PAGE                                                                   
*                                                                               
* ERROR AND ABNORMAL HANDLER                                                    
*                                                                               
DONE     RES      0                                                             
         BAL,R8   RELTEMP           RELEASE TEMP SPACE                          
         PULL     2,R3              RESTORE STACK                               
         B        STOPP             AND EXIT                                    
         TITLE    'SUBROUTINES'                                                 
*                                                                               
* CONVERT - THIS ROUTINE CONVERTS A VALUE IN R3 TO EBCDIC IN R2/3               
*                                                                               
* NO REGISTERS ARE ALTERED AND THE LINK IS R0                                   
*                                                                               
CONVERT  RES      0                                                             
         PUSH     3,R4              SAVE WORKING SPACE                          
         LI,R6    7                 STORE INDEX                                 
         LW,R4    R3                DATA TO CONVERT                             
CLOOP    SCD,R4   -4                GET ONE DIGIT                               
         SLS,R5   -28               RIGHT JUST. AND MASK                        
         AI,R5    '0'               ADD ZONE                                    
         CI,R5    '9'               IS IT TOO BIG                               
         BLE      %+2               NO                                          
         AI,R5    'A'-'0'-10        YES, ADJUST                                 
         STB,R5   R2,R6             STORE IN RESULT                             
         AI,R6    -1                                                            
         BGEZ     CLOOP             LOOP TILL DONE                              
         PULL     3,R4              RESTORE REGISTERS                           
         B        *R0                                                           
*                                                                               
         PAGE                                                                   
*                                                                               
* CONVERT2 - THIS ROUTINE IS THE SAME AS CONVERT, BUT FILLER                    
* LEADING ZEROS                                                                 
*                                                                               
CONVERT2 RES      0                                                             
         PUSH     2,R0                                                          
         BAL,R0   CONVERT                                                       
         LI,R1    7                 COUNTER                                     
CLOOP2   LB,R0    R2                PICK UP A BYTE                              
         CI,R0    '0'               IS IT A ZERO                                
         BNE      CONVERT3          NO, FINISH UP                               
         LI,R0    ' '               PICK UP A BLANK                             
         STB,R0   R2                AND BLANK CHARACTER                         
         SCD,R2   8                 SHIFT EBCDIC                                
         BDR,R1   CLOOP2            AND LOOP TIL DONE                           
         SCD,R2   8                                                             
CONVERT4 PULL     2,R0              RESTORE REGISTERS                           
         B        *R0                                                           
************************************                                            
CONVERT3 RES      0                                                             
         AI,R1    1                                                             
         SLS,R1   3                 TIMES 8                                     
         SCD,R2   0,R1              POSITION EBCDIC                             
         B        CONVERT4          AND EXIT                                    
*                                                                               
*                                                                               
         TITLE    'SYMBOL TABLE'                                                
*                                                                               
SYMBOL   RES      0                                                             
         DATA     SYMBOLEND-SYMBOL-1                                            
*                                                                               
         SYMBOL   'RBM     ',RBM                                                
         SYMBOL   'OLAYFWA ',OLAYFWA                                            
         SYMBOL   'S:TRACE ',S:TRACE                                            
         SYMBOL   'DCT1    ',DCT1                                               
         SYMBOL   'DCT2    ',DCT2                                               
         SYMBOL   'DCT3    ',DCT3                                               
         SYMBOL   'DCT5    ',DCT5                                               
         SYMBOL   'DCT6    ',DCT6                                               
         SYMBOL   'DCT7    ',DCT7                                               
         SYMBOL   'DCT11   ',DCT11                                              
         SYMBOL   'DCT12   ',DCT12                                              
         SYMBOL   'DCT13   ',DCT13                                              
         SYMBOL   'DCT16   ',DCT16                                              
         SYMBOL   'DCT19   ',DCT19                                              
         SYMBOL   'DCT20   ',DCT20                                              
         SYMBOL   'DCT21   ',DCT21                                              
         DO       #ERRORLOG                                                     
         SYMBOL   'DCT#IO  ',DCT#IO                                             
         SYMBOL   'DCT#ERR ',DCT#ERR                                            
         FIN                                                                    
         SYMBOL   'DCTMOD  ',DCTMOD                                             
         DO1      #DEBUG                                                        
         SYMBOL   'DCTDEBUG',DCTDEBUG                                           
         SYMBOL   'IOQ1    ',IOQ1                                               
         SYMBOL   'IOQ2    ',IOQ2                                               
         SYMBOL   'IOQ3    ',IOQ3                                               
         SYMBOL   'IOQ4    ',IOQ4                                               
         SYMBOL   'IOQ5    ',IOQ5                                               
         SYMBOL   'IOQ7    ',IOQ7                                               
         SYMBOL   'IOQ8    ',IOQ8                                               
         SYMBOL   'IOQ9    ',IOQ9                                               
         SYMBOL   'IOQ10   ',IOQ10                                              
         SYMBOL   'IOQ11   ',IOQ11                                              
         SYMBOL   'IOQ12   ',IOQ12                                              
         SYMBOL   'IOQ13   ',IOQ13                                              
         SYMBOL   'IOQ14   ',IOQ14                                              
         DO1      #ERRORLOG                                                     
         SYMBOL   'IOQERROR',IOQERROR                                           
         SYMBOL   'CIT1    ',CIT1                                               
         SYMBOL   'CIT2    ',CIT2                                               
         SYMBOL   'CIT3    ',CIT3                                               
         SYMBOL   'CIT5    ',CIT5                                               
         SYMBOL   'CIT6    ',CIT6                                               
         SYMBOL   'RFT1    ',RFT1                                               
         SYMBOL   'RFT2    ',RFT2                                               
         SYMBOL   'RFT3    ',RFT3                                               
         SYMBOL   'IOQECB  ',IOQECB                                             
         SYMBOL   'RFT4    ',RFT4                                               
         SYMBOL   'RFT5    ',RFT5                                               
         SYMBOL   'RFT6    ',RFT6                                               
         SYMBOL   'RFT7    ',RFT7                                               
         SYMBOL   'RFT8    ',RFT8                                               
         SYMBOL   'RFT9    ',RFT9                                               
         SYMBOL   'RFT10   ',RFT10                                              
         SYMBOL   'RFT11   ',RFT11                                              
         SYMBOL   'RFT12   ',RFT12                                              
         SYMBOL   'RFT13   ',RFT13                                              
         SYMBOL   'RFT14   ',RFT14                                              
         SYMBOL   'RFT15   ',RFT15                                              
         SYMBOL   'RFT16   ',RFT16                                              
         SYMBOL   'RFT17   ',RFT17                                              
         SYMBOL   'LMINAME ',LMINAME                                            
         SYMBOL   'LMIJID  ',LMIJID                                             
         SYMBOL   'LMISTAT ',LMISTAT                                            
         DO1      #MAP                                                          
         SYMBOL   'LMISDT  ',LMISDT                                             
         SYMBOL   'LMIRTS  ',LMIRTS                                             
         DO       #ECB                                                          
         SYMBOL   'LMIMAXS ',LMIMAXS                                            
         SYMBOL   'LMIMAXR ',LMIMAXR                                            
         SYMBOL   'LMIAET  ',LMIAET                                             
         SYMBOL   'LMISECB ',LMISECB                                            
         SYMBOL   'LMIRECB ',LMIRECB                                            
         FIN      #ECB                                                          
        DO1      #MAP                                                           
         SYMBOL   'LMIRFT  ',LMIRFT                                             
         SYMBOL   'STIRTSB ',STIRTSB                                            
         SYMBOL   'STIOVID ',STIOVID                                            
         SYMBOL   'STIJID  ',STIJID                                             
         SYMBOL   'STILMID ',STILMID                                            
         SYMBOL   'STIPRIO ',STIPRIO                                            
         SYMBOL   'STITCB  ',STITCB                                             
         SYMBOL   'STICOUNT',STICOUNT                                           
         SYMBOL   'STISTAT ',STISTAT                                            
         SYMBOL   'STISPCE ',STISPCE                                            
         SYMBOL   'SJI1    ',SJI1                                               
         SYMBOL   'SJI2    ',SJI2                                               
         SYMBOL   'SJI3    ',SJI3                                               
         SYMBOL   'OVLOAD1 ',OVLOAD1                                            
         SYMBOL   'OVLOAD2 ',OVLOAD2                                            
         SYMBOL   'OVLOAD3 ',OVLOAD3                                            
         SYMBOL   'EPIEP   ',EPIEP                                              
         SYMBOL   'GTBL    ',GTBL                                               
         SYMBOL   'CRASHLOC',CRASHLOC                                           
         SYMBOL   'CRASHREG',CRASHREG                                           
         DO1      #MAP*#CRASH                                                   
         SYMBOL   'CRASHMAP',CRASHMAP                                           
         DO       #SIGMA9                                                       
         SYMBOL   'CRASHI1 ',CRASHI1                                            
         SYMBOL   'CRASHI2',CRASHI2                                             
         SYMBOL   'CRASHI3 ',CRASHI3                                            
         FIN      #SIGMA9                                                       
         SYMBOL   'SENSESW ',SENSESW                                            
         DO1      #CRASH                                                        
         SYMBOL   'CRASHMSG',CRASHMSG                                           
         SYMBOL   'CCBUF   ',CCBUF                                              
         SYMBOL   'TERM *  ',TERM                                               
         SYMBOL   'TMTYC * ',TMTYC                                              
         SYMBOL   'S:TEMPN ',S:TEMPN                                            
         SYMBOL   'S:TEMP  ',S:TEMP                                             
         DO       #ERRORLOG                                                     
         SYMBOL   'LOGSTACK',LOGSTACK                                           
         SYMBOL   'LOSTLOGS',LOSTLOGS                                           
         SYMBOL   'GOODLOGS',GOODLOGS                                           
         FIN      #ERRORLOG                                                     
SYMBOLEND RES     0                                                             
         TITLE    'FPT DEFINITIONS'                                             
*                                                                               
FPT      COM,8,24 AF(1),AF(2)                                                   
*                                                                               
BINARY   EQU      X'20000'                                                      
OPLBL    EQU      3                                                             
FILE     EQU      1                                                             
         TITLE    'FPTS'                                                        
*                                                                               
TTTT     RES      1                 SPARE ONE FOR MOVE                          
*                                                                               
FPT4     FPT      X'11',LODCB-TTTT  FPT TO PRINT MESSAGES                       
         DATA     P1+P2+P3+P4+P6+F3                                             
         DATA     DONE,DONE         ERR AND ABN                                 
LOBUFPTR DATA     0                 MESSAGE ADDRESS                             
LOBC     DATA     0                 MESSAGE BYTE COUNT                          
         DATA     1                 BTD FOR ALL TEXTC                           
         TITLE    'MESSAGES'                                                    
*                                                                               
*                                                                               
SYMHEAD  TEXTC    '   SYMBOL.....VALUE    SYMBOL.....VALUE',;                   
                 '    SYMBOL.....VALUE    SYMBOL.....VALUE   '                  
FILLER   TEXTC    '                       '                                     
SYMFILL  EQU      FILLER+1                                                      
*                                                                               
ZEROMSG  TEXTC    ' *** ZEROS ***'                                              
*                                                                               
TOPMSG   DATA,1   3,X'F1',X'40',X'40'                                           
*                                                                               
         TITLE    'DCBS'                                                        
*                                                                               
LODCB    FPT      5,3               DCB FOR LO PRINTING                         
         FPT      10,3              NRT - 10,  OPLB - LO                        
         DATA     0                                                             
         DATA     DONE,DONE                                                     
*                                                                               
*                                                                               
TEMPEND  RES      0                                                             
*                                                                               
         OLAYEND                                                                
         END                                                                    
