         TITLE    '** TIO1 **'                                                  
         PCC      0                                                             
         SYSTEM   SIG9P                                                         
         SYSTEM   OPTIONS                                                       
         SPACE    2                                                             
*                                                                               
*                                                                               
*                                                                               
         DEF      A:TIO1                                                        
         DEF      TI                                                            
         DEF      TIO1EX01                                                      
         DEF      TISABENX                                                      
TIO1     EQU      %                                                             
A:TIO1   EQU      TIO1                                                          
OLAYFLAG EQU      'TIO1'                                                        
         SYSTEM   CPRMON                                                        
         TITLE    '** TIO1 - SECONDARY TASK INITIATION **'                      
*                                                                               
*        INITSEC  ROUTINE TO PERFORM  SECONDARY TASK  INITIATION                
*                 ENTERED BY TASK DISPATCHER AFTER  INIT CAL PROCESSING         
*                                                                               
*                 AT ENTRY:                                                     
*                             LMI ENTRY ESTABLISHED                             
*                             STCB CREATED                                      
*                             STI ENTRY ESTABLISHED                             
*                             INIT ECB CREATED WITH ATTACHED DATA AREA          
*                                   CONTAINING:                                 
*                                       DCB FOR LOAD MODULE                     
*                                       READ FPT FOR READING HEADERS AN         
*                                       ROOTS                                   
*                                                                               
*                             LMI4 CONTAINS THE ADDRESS                         
*                             OF THE INIT ECB                                   
*                                                                               
*                                                                               
*                                                                               
*                                                                               
*                                                                               
*                                                                               
         PAGE                                                                   
TIS01    EQU      %                                                             
         LI,R15   TYC66             NO SPACE ERROR CODE                         
         B        TISABEND          ABNORMAL END                                
******** GET ACI SPACE AND SET TO NO ACCESS                                     
TIS02    EQU      %                                                             
TI       EQU      %                                                             
         LB,R6    TCBPOINT          TASK ID                                     
         LB,R5    STILMID,R6        LMI INDEX                                   
         LI,R7    TISACI            ACI SPACE                                   
         BAL,R8   GETTEMP           GET SPACE                                   
         B        TIS01             NO SPACE                                    
         BAL,R8   TISCHN            CHAIN TO TASK                               
         ENABLE                                                                 
         LI,R1    15                                                            
         LW,R0    TMACIMC+2,R1      MOVE PROTOTYPE ACI                          
         STW,R0   *R7,R1            INTO TASK ACI                               
         BDR,R1   %-2                                                           
         DISABLE                                                                
         BAL,R8   TISDECHN          DECHAIN ACI SPACE                           
         LW,R0    TMACIMC+2                                                     
         STW,R0   0,R7              ACI WORD 0                                  
         LI,R2    STCBACI           OFFSET TO ACI POINTER                       
         STW,R7   *TCBPOINT,R2      SET POINTER TO ACI                          
         ENABLE                                                                 
******** DONE WITH ACI NOW SET UP TO GET PAGE OF PRIVATE CONTEXT                
         LI,R7    TISTSD            SPACE COUNT FOR TASK RES PAGE SD            
         BAL,R8   GETTEMP           GET SPACE                                   
         B        TIS01             NO SPACE-ERROR                              
         BAL,R8   TISCHN            CHAIN SPACE                                 
         LI,R1    TISTRPL           NUMBER OF WORDS TO BE MOVED                 
TIS04    EQU      %                                                             
         LW,R8    TISTRPSD-1,R1     GET PROTOTYPE AND                           
         STW,R8   *R7,R1            MOVE IT                                     
         BDR,R1   TIS04             B FOR MORE                                  
         LI,R9    TISTRPMP          OFFSET TO MAP                               
         AW,R9    R7                POINTS TO MAP IMAGE                         
         AND,R9   M24               MASK                                        
         STW,R7   R10               AST ENTRY FOR TRP SD                        
         AND,R10  M24               MASK                                        
         AW,R10   Y60               MAKE IT ACTIVE                              
         LI,R2    STCBAST           OFFSET TO AST POINTER                       
         LW,R11   *TCBPOINT,R2      GET AST POINTER FROM STCB                   
         LI,R1    2                 OFFSET TO STORE NEW(SD )                    
         BAL,R8   TISDECHN          DE CHAIN  SPACE                             
         STW,R9   *R7               SET FIRST WORD OF SD CONTROL DW             
         STW,R10  *R11,R1           SET NEW AST ENTRY                           
         LW,R8    LMISDT,R5         GET CHAIN WORD                              
         LB,R8    R8                GET TASK ID                                 
         STB,R8   R7                PUT IN NEW CHAIN WORD                       
         STW,R7   LMISDT,R5         STORE IN  LMI                               
         ENABLE                                                                 
         LI,R0    0                 ACCESS CODE = ALL ACCESS                    
         BAL,R8   MMGTRP            GET A TASK RESERVED PAGE                    
         B        TIS01             NO  PAGE  AVAILABLE                         
         SLS,R14  9                 MAKE PAGE ADDRESS INTO  WORD ADD.           
         STW,R14  R9                SAVE IN R9                                  
         LI,R8    256               OFFSET TO LM HEADER BUFFER                  
         AW,R8    R9                POINTS TO BUFFER                            
******** NOW WE HAVE A PAGE OF CONTEXT SET UP THE CONTEXT AREA                  
******** CONTROL TABLE                                                          
         STW,R8   *R9               CONSTRUCT CONTROL TABLE                     
         AI,R9    1                 STEP TO NEXT WORD OF CONTROL TABLE          
         LI,R1    7                 LOOP COUNT                                  
TIS05    EQU      %                                                             
         AI,R8    -16               POINT TO PUB-LIB BUFFER                     
         STW,R8   *R9               STORE IN CONTROL TABLE                      
         AI,R9    1                 NEXT WORD                                   
         BDR,R1   TIS05             B FOR NEXT ENTRY                            
******** NEXT SET UP TEMP AST FOR OVERLAY, TASK AND JOB RES PAGES               
         LW,R4    TCBPOINT          ADDRESS OF STCB                             
         LW,R10   STCBAST,R4        AST ADDRESS                                 
         LI,R0    TISJRP#           SEGMENT NUMBER                              
         AW,R0    Y04               JOB SHARE FLAG FAKE OV TAB                  
         BAL,R8   TISEARCH          FIND SD                                     
         B        TICRASH           NOT FOUND                                   
         LI,R1    1                                                             
         LI,R0    TISASTA           ACTIVE ENTRY FLAGE                          
         STB,R0   R9                FORMS JOB RES AST ENTRY                     
         STW,R9   *R10,R1           SET IN TEMP AST                             
         LI,R4    SDTACT            OFFSET TO USE COUNTS                        
         LI,R0    3                 LOOP COUNT                                  
TIS06    EQU      %                                                             
         MTB,1    *R9,R4            INCREMENT TA,TE,TU                          
         AI,R4    1                 MOVE TO NEXT BYTE                           
         BDR,R0   TIS06             B FOR NEXT BYTE                             
         ENABLE                                                                 
         BAL,R8   LOADMAP           LOAD MAP FOR JOB RES PAGES                  
*******  NOW SET UP LMIRFT SPACE TO BOOKKEEP HIS OPENS/CLOSES                   
         BAL,R8   TIRFT             GET LMIRFT POINTER IN R7                    
         B        TISABEND          NO SPACE                                    
         STW,R7   LMIRFT,R5         SET LINK WORD IN LMI                        
         ENABLE                                                                 
******** NEXT WE WILL READ IN THE LOAD MODULE HEADER                            
         LW,R1    LMI4,R5           GET ECB ADDRESS IN R1                       
         LW,R9    0,R1              GET DATA AREA ADDRESS                       
         AI,R9    TISFPT            POINT TO FPT                                
         LW,R10   *R14              BUFFER ADDRESS                              
         LI,R11   0                 GRANULE ZERO                                
         LI,R12   100               HEADER BYTE COUNT                           
         BAL,R8   TISREAD           READ HEADER                                 
         B        TISABEND          ERROR IN READING                            
******** THE HEADER IS IN  NOW VALIDATE HEADER INFORMATION                      
         LW,R0    *R10              GET FIRST WORD OF HEADER                    
         LB,R0    R0                GET FLAGS                                   
         CI,R0    LML               IS IT A  PUBLIC LIBRARY LM                  
         BANZ     TIS28X            B IF YES                                    
         CI,R0    LMPRI             IS IT A PRIMARY LM                          
         BANZ     TIS29X            B IF YES (TYCB1)                            
         CI,R0    LMF               FOREGROUND LOAD MODULE                      
         BANZ     TIS06E            FOR LM - CAN LOAD UNCONDITIONALLY           
         BIFBKG   TIS06E                BKG, LM MUST BE BKG                     
TIS06C   LI,R15   TYCB7             ERROR CODE, FGD/BKG                         
         B        TISABEND              CONFLICT                                
TIS06E   EQU      %                                                             
******** NEXT GET PERMANENT AST SPACE AND SET OVERLAY AST                       
******** AND TASK RESERVED PAGES AST ENTRY                                      
         LI,R7    LMNSEGS           OFFSET TO NUMBER OF SEGMENTS                
         LB,R7    *R10,R7           GET  # OF SEGS                              
         AI,R7    TISSEGS           ADD SYSTEM SEGMENT COUNT                    
         BAL,R8   GETTEMP           GET SPACE                                   
         B        TISABEND          B IF NO SPACE                               
         BAL,R8   TISCHN            CHAIN SPACE                                 
         LI,R1    STCBAST           OFFSET TO AST POINTER                       
         LW,R10   *TCBPOINT,R1      GET AST POINTER                             
         LB,R2    R7                GET NUMBER OF ENTRIES                       
         AI,R2    -2                GIVES OFFSET FOR JOB AND TASK ASTS          
         LCI      3                 SET FOR THREE WORDS                         
         LM,R11   *R10              GET CURRENT AST ENTRIES                     
         STW,R11  *R7               SET OVERLAY AST                             
         LCI      2                 SET FOR 2 WORDS                             
         STM,R12  *R7,R2            SET JOB AND TASK ASTS                       
         BAL,R8   TISDECHN          DECHAIN SPACE                               
         XW,R7    *TCBPOINT,R1      SET NEX AST PONTER                          
         BAL,R8   RELTEMP           RELEASE OLD SPACE                           
         LW,R7    *TCBPOINT,R1      GET NEX AST PONINTER IN R7                  
         ENABLE                                                                 
******** NOW READ IN ROOT PART ONE                                              
         STW,R14  R9                POINTS TO CONTEXT PAGE                      
         AI,R9    TISCTX1                                                       
         LW,R9    *R9               GET ADDRESS OF  CONTEXT AREA                
         LI,R1    TISLMHD           OFFSET TO LM HEADER ADDRESS                 
         LW,R13   *R14,R1           GET ADDRESS OF HEADER                       
         LI,R1    RP1VMBL           MEMORY BYTE LENGTH                          
         LW,R0    *R13,R1           GET  VM BL                                  
         AI,R0    2047              FOR ROUNDING UP TO PAGE                     
         SLS,R0   5                 POSITION  #OF PAGES IN BYTE 1               
         AND,R0   Y00FF             MASK                                        
TIS06A   AI,R0    X'9000'           SEGMENT NUMBER                              
         STW,R0   *R9               PLACE IN PSEUDO  OVLOAD ENTRY               
         AI,R9    5                 POINT TO VM WO                              
         LI,R1    RP1VMWO                                                       
         LW,R0    *R13,R1           GET  WORD ORIGIN                            
         STW,R0   *R9               PLACE IN  PSEUDO  OV ENTRY                  
         AI,R9    -5                RESTORE  TO POINT TO START OF OV            
         BAL,R8   TISD              CONSTRUCT A SEGMENT DESCRIPTOR              
         B        TISABENX          NO SPACE                                    
         AI,R7    1                 POINT TO ROOT PART ONE  ENTRY               
         STW,R9   *R7               STORE ROOT PART ONE AST ENTRY               
         LW,R9    R14               POINTS TO CONTEXT PAGE                      
         AI,R9    TISCTX1           OFFSET TO  CONTEXT AREA 1                   
         LW,R9    *R9               GET  ADDRESS OF AREA                        
         LCI      3                 SET FOR LOADING 3 WORDS                     
         LM,R0    TISAFPT1          GET ACTIVATE  FPT FOR ROOT PART ONE         
         STM,R0   *R9               PLACE IN  CONTEXT AREA                      
         CAL1,7   *R9               ACTIVATE  TO GET REAL MEMORY                
         AI,R9    TISATYC           OFFSET TO TYC PARAMETER                     
         LB,R15   *R9               GET TYC                                     
         CI,R15   TYCNORM           CHECK FOR NORMAL COMPLETION                 
         BNE      TISABENX          B IF SOME KIND OF ERROR                     
         LW,R1    LMI4,R5           GET ECB ADDRESS IN R1                       
         LW,R9    0,R1              GET DATA AREA ADDRESS                       
         AI,R9    TISFPT            POINT TO FPT                                
         LW,R1    *R14              GET ADDRESS OF LM HEADER                    
         AI,R1    LMRP1WO           OFFSET TO ROOT PART ONE WORD ORIGIN         
         LW,R10   *R1               GET WORD ORIGIN                             
*ADD CODE HERE FOR VALIDITY CHECK IF NECESSARY                                  
         AI,R1    1                 MOVE TO LM RP1 BYTE LENGTH                  
         LW,R12   *R1               GET BYTE  LENGTH                            
         LI,R11   RP1GO             GRANULE OFFSET                              
         BAL,R8   TISREAD           READ ROOT PART ONE                          
         B        TISABENX          ERROR CANNOT READ                           
******** ROOT PART ONE IS IN - SEE OF THERE IS A ROOT PART TWO                  
         LW,R0    *R14              ADDRESS OF HEADER                           
         LI,R1    LMRP2LMB          OFFSET TO RP2 MEM. BYTE LENGTH              
         LW,R1    *R0,R1            GET RP2 MEM BYTE LENGHT                     
         AND,R1   M24               MASK                                        
         BEZ      TIS07             B TO SKIP ROOT PART TWO                     
******** NOW READ IN ROOT PART TWO                                              
         LI,R4    TISCTX2           USE CONTEX AREA TWO                         
         LW,R4    *R14,R4           POINTS TO  CONTEXT AREA TWO                 
         LI,R1    LMRP2MBL          OFFSET TO ROOT PART TWO MEM BYTE LG         
         LW,R13   *R14              GET ADDRESS OF HEADER                       
         LW,R9    *R13,R1           GET RP2 BYTE LENGTH                         
         AI,R9    2047              ROUND UP                                    
         SLS,R9   5                 POSITION NUMBER OF PAGES IN BYTE 1          
         AND,R9   Y00FF             MASK                                        
TIS06B   AI,R9    X'9001'           ROOT PART TWO  SEGMENT NUMBER               
         STW,R9   *R4               PLACE IN PSEUDO OV TABLE                    
         AI,R4    5                 POINT TO  VMWO  FOR  SEGMENT                
         LI,R1    LMRP2WO           OFFSET TO ROOT PART TWO WORD ORIGIN         
         LW,R9    *R13,R1           GET WORD ORIGIN                             
         STW,R9   *R4               PLACE IN  PSEUDO OV TABLE                   
         AI,R4    -5                POINT TO  START OF CONTEXT AREA             
         STW,R4   R9                                                            
         BAL,R8   TISD              BUILD A SEGMENT DISCRIPTOR                  
         B        TISABENX          ERROR NO SPACE                              
         LI,R7    STCBAST           OFFSET TO AST POINTER                       
         LW,R7    *TCBPOINT,R7      GET AST POINTER                             
         AI,R7    2                 POINT TO FIRST SLOT AFTER ROOT PART         
         STW,R9   *R7               PLACE SD ADDRESS IN AST                     
         LI,R4    TISCTX1           USE CONTEXT AREA ONE                        
         LW,R4    *R14,R4           GET ADDRESS OF CONTEXT AREA                 
         LCI      3                                                             
         LM,R0    TISAFPT2          GET ACTIVATE FPT                            
         STM,R0   *R4               PLACE IN  CONTEXT AREA                      
         CAL1,7   *R4               ACTIVATE TO GET REAL MEMORY                 
         AI,R4    TISATYC           OFFSET TO  TYC  WORD                        
         LB,R15   *R4               GET TYC FOR ACTIVATE                        
         CI,R15   TYCNORM           CHECK FOR ERRORS                            
         BNE      TISABENX          B IF NOT OK                                 
         LW,R1    LMI4,R5           GET ECB ADDRESS IN R1                       
         LW,R9    0,R1              GET DATA AREA ADDRESS                       
         AI,R9    TISFPT            POINT TO FPT                                
         LW,R1    *R14              GET ADDRESS OF LM HEADER                    
         AI,R1    LMRP2WO           OFFSET TO ROOT PART TWO WORD ORIGIN         
         LW,R10   *R1               GET WORD ORIGIN                             
*ADDCODE HERE FOR VALIDITY CHECK                                                
         AI,R1    1                 MOVE TO LM RP2 BYTE LENGTH                  
         LW,R12   *R1               GET BYTE LENGTH                             
         AI,R1    1                 MOVE TO LM RP2 GRANULE ORGIN                
         LW,R11   *R1               GET GRANULE START                           
         BAL,R8   TISREAD           READ IN  ROOT PART TWO                      
         B        TISABENX          ERROR                                       
******** ROOT PART TWO IS IN NOW PROCESS THE SEGMENTS                           
TIS07    EQU      %                                                             
         LW,R13   *R14              GET ADDRESS OF HEADER                       
         LI,R1    LMRTSDW           OFFSET TO  RTS DW  PROTOTYPE                
         LD,R0    *R13,R1           GET  STACK DOUBLE WORD                      
         DISABLE                                                                
         LD,R2    LMIRTS,R5         GET CURRENT STACK DOUBLE WORD               
         STD,R0   LMIRTS,R5         SET NEW  DOUBLE WORD                        
         ENABLE                                                                 
******** NOW WE ARE USING THE TASKS REAL RBM STACK - SO GET                     
******** RID  OF TEMPORARY RTS STACK                                            
         AND,R3   X7FFF             MASK                                        
         SW,R2    R3                SUBTRACT WORD COUNT FROM TOP OF STA         
         MTW,0    R3                WAS THERE ANYTHING IN THE STACK             
         BEZ      TIS08             B IF NO                                     
         LI,R1    1                 LOOP INDEX                                  
TIS07A   EQU      %                                                             
         LW,R8    *R2,R1            GET WORD OUT OF OLD STACK                   
         PUSH     R8                PUT IN NEW STACK                            
         AI,R1    1                                                             
         BDR,R3   TIS07A            B FOR NEXT WORD                             
TIS08    EQU      %                                                             
         AI,R2    1                 R2 NOW POINTS TO TSPACE HEAD                
         LI,R7    PINITRTS          AMOUNT OF TEPACE                            
         STB,R7   R2                                                            
         LW,R7    R2                SETUP FOR DECHAINING                        
         BAL,R8   RELTEMP           GO RELEASE SPACE (DISABLED)                 
******** NEXT SET UP HIS PCBPOINT- SAVE THE CURRENT PCBPOINT FLAGS              
         LW,R13   *R14              GET ADDRESS OF HEADER                       
         LI,R1    LMRP1WO           OFFSET TO RP1 WO                            
         LW,R13   *R13,R1           GET ADDRESS OF PCB                          
         LI,R1    STCBPCB           OFFSET TO  PCB POINTER                      
         LW,R0    PCBPOINT          GET CURRENT PCB  ENTRY                      
         AND,R0   YFF               STRIP OFF ADDRESS - SAVE FLAGS              
         AND,R13  M24               STRIP OFF FLAGS  SAVE ADDRESS               
         OR,R13   R0                FORM ENTRY (PCB POINTER)                    
         STW,R13  PCBPOINT          UPDATE PCB POINTER                          
         LI,R1    PCBM:SL           OFFSET TO M:SL ADDRESS                      
         LW,R13   *PCBPOINT,R1                                                  
         BEZ      TIS09             B IF THERE IS NO M:SL                       
*********ASSIGN USER M:SL TO LOAD MODULE FILE                                   
*        R13 CONTAINS M:SL ADDRESS                                              
         LW,R1    LMI4,R5           INIT ECB ADDRESS                            
         LW,R9    ECBDATA,R1        INIT CONTROL SPACE                          
         AI,R9    1                 INIT DCB ADDRESS                            
         LI,R4    TISCTX1                                                       
         LW,R4    *R14,R4           ADDR OF CONTEXT AREA 1                      
         AI,R4    -1                                                            
         LI,R1    TISGASN%-TISGASN                                              
         LW,R0    TISGASN-1,R1                                                  
         STW,R0   *R4,R1            MOVE GETASSIGN FPT TO CONTEXT               
         BDR,R1   %-2                                                           
         AI,R4    1                                                             
         AWM,R4   TISGASN1-TISGASN,R4 RELOCATE FILE AREA/NAME PTR               
         AWM,R4   TISGASN2-TISGASN,R4 RELOCATE ACNT NAME PTR                    
         CAL1,1   *R4               GET INIT DCB ASSIGNMENT                     
         LW,R0    TISASN                                                        
         STW,R0   *R4               CHANGE GETASN TO ASSIGN                     
         DO       #DFACNT                                                       
         LCI      2                                                             
         LM,R0    TISGASNA-TISGASN,R4 GET ACCOUNT NAME                          
         CD,R0    SYSACNT                                                       
         BNE      %+3               B IF NOT SYSTEM ACNT                        
         LW,R0    TISASN0           P-BITS FOR DFLT ACNT                        
         STW,R0   TISGASN0-TISGASN,R4                                           
         FIN                        #DFACNT                                     
         CAL1,1   *R4               ASSIGN M:SL                                 
*********CLOSE INIT DCB                                                         
TIS09    RES      0                                                             
         LW,R1    LMI4,R5           GET ADDRESS OF ECB IN R1                    
         LW,R9    0,R1              ADDRESS OF DATA AREA                        
         AI,R9    1                 POINT TO TEMP DCB                           
         LI,R10   X'15'             CLOSE FPT CODE                              
         STB,R10  R9                                                            
         LI,R10   0                 2ND WORD OF FPT -NO PARAMETERS              
         CAL1,1   R9                FPT IS IN R9 AND R10                        
******** NOW SET UP TEMPORARY AST ENTRIES SO THEY CAN BE SORTED                 
         LW,R13   *R14              GET ADDRESS OF HEADER                       
         LB,R13   *R13              GET HEADER FLAG BYTE                        
         CI,R13   LMB               IS SMM REQUIRED                             
         BANZ     TIO1EX01          B IF YES                                    
TIS10A   LI,R1    PCBOVLD           OFFSET TO OVLOAD ADDRESS                    
         LW,R4    *PCBPOINT,R1      GET OVLOAD TABLE ADDRESS                    
         LW,R7    *R4               GET NUMBER OF ENTRIES                       
         AI,R7    -2                SUB 2 TO SKIP ROOTS                         
         BLEZ     TIO1EX01          B IF NO SEGMENTS                            
         STW,R7   R13               SAVE FOR ORDERING AST'S                     
         AI,R4    23                POINT TO FIRST ENTRY AFTER ROOT             
         LI,R12   2                 OVLOAD TABLE INDEX                          
*                                   R4 HAS POINTER TO OVLOAD TABLE              
*                                   R12 HAS OVLOAD INDEX                        
*                                   R3 HAS POINTER TO AST                       
*                                   R7 HAS LOOP COUNT                           
         SLS,R12  8                 POSITION OV INDEX IN BYTE 2                 
TIS11    EQU      %                                                             
         LW,R9    0,R4              GET WORD ZERO OF OVLOAD ENTRY               
         AND,R9   XOVSMSK           EXTRACT SHARABILITY CODE                    
         CW,R9    XOVSMSK           COMPARE FOR SMM SHARABILITY                 
         BE       TIS13             SKIP SEG IF SMM                             
         LW,R9    OVVMWO,R4         GET WORD ORIGIN FOR THIS SEGMENT            
         SLS,R9   -9                MAKE IT A PAGE ADDRESS                      
         OR,R9    R12               SET INDEX NUMBER                            
         OR,R9    Y8                SET SD NEEDED FLAG                          
         BAL,R8   TISAST            SET AST ENTRY IN AST                        
         B        TISABEND          B IF UNABLE TO INSERT ENTRY                 
TIS13    RES      0                                                             
         AI,R12   X'100'            INCREMENT INDEX                             
         AI,R4    OVNXSEGW          MOVE TO NEXT SEGMENT                        
         BDR,R7   TIS11             B FOR NEXT SEGMENT                          
TIO1EX01 B        TIS15                                                         
*                                                                               
TIS28X   EQU      %                                                             
         LI,R15   TYCB0                                                         
         B        TISABEND                                                      
TIS29X   EQU      %                                                             
         LI,R15   TYCB1                                                         
         B        TISABEND                                                      
*                                                                               
TISGASN  GEN,1,7,1,23  1,X'09',1,R9  GET ASSIGNMENT OF DCB                      
TISGASN0 DATA     P4+P14+F7                                                     
TISGASN1 DATA     TISGASNF-TISGASN  FILE/AREA NAME POINTER                      
TISGASN2 DATA     TISGASNA-TISGASN    ACNT NAME POINTER                         
TISGASN% EQU      %                                                             
TISGASNF EQU      %                 RELATIVE POSITION OF FILE NAME              
TISGASNA EQU      %+3               RELATIVE POSITION OF ACNT NAME              
*                                                                               
TISASN   GEN,1,7,1,23  1,X'08',1,R13                                            
TISASN0  DATA     P4+F7             P-BITS FOR NO ACNT NAME                     
*                                                                               
TISTRPSD EQU      %                 PROTOTYPE TASK RES PAGES SD                 
         GEN,8,7,8,9 1+#SIGMA9M,0,252,0                                         
         GEN,6,3,3,4,16 0,5,3,0,X'9003' TASK RESERVED PAGES,ACTIVE SEG#         
         DATA     0                 LMI,SDTFLINK                                
         DATA,1   1,1,1,0           TA=1,TE=1,TU=1,0                            
         DATA,1   0,4,1,0           RP=0,VP=4,ACICNT=1,0                        
         DATA     -1                ACCESS PROTECTION                           
TISTRPL  EQU      %-TISTRPSD                                                    
TISOV0X  DATA  0                                                                
TISAFPT1 DATA     X'52809000'       ACTIVATE FPT FOR ROOT PART ONE              
         DATA     X'00400001'                                                   
         DATA     0                                                             
TISAFPT2 DATA     X'52809001'       ACTIVATE FOR ROOT PART TWO                  
         DATA     X'00400001'                                                   
         DATA     0                                                             
TISFPT3  DATA     X'52800000'                                                   
         DATA     X'00400001'                                                   
         DATA     0                                                             
TISABEND EQU      %                                                             
TISABENX EQU      %                                                             
         B        TIO2ABEN          EXIT OVERLAY                                
         SPACE    2                                                             
         OLAYEND                                                                
         SPACE    2                                                             
         END                                                                    
